Функция ЕСЛИ() в MS EXCEL

Функция ЕСЛИ(), английский вариант IF(), используется при проверке условий. Например, =ЕСЛИ(A1>100;"Бюджет превышен";"ОК!"). В зависимости от значения в ячейке А1 результат формулы будет либо "Бюджет превышен" либо "ОК!".

Функция ЕСЛИ()относится к наиболее часто используемым функциям.

Синтаксис функции

ЕСЛИ(лог_выражение;значение_если_истина;[значение_если_ложь])

Лог_выражение   — любое значение или выражение, принимающее значения ИСТИНА или ЛОЖЬ.
=ЕСЛИ(A1>=100;"Бюджет превышен";"ОК!")
Т.е. если в ячейке A1 содержится значение большее или равное 100, то формула вернет ОК!, а если нет, то Бюджет превышен.

В качестве аргументов функции, могут участвовать формулы, например:
=ЕСЛИ(A1>100;СУММ(B1:B10);СУММ(C1:C10))
Т.е. если в ячейке A1 содержится значение >100, то суммирование ведется по столбцу B, а если меньше, то по столбцу С.

Вложенные ЕСЛИ

В EXCEL 2007 в качестве значений аргументов значение_если_истина и значение_если_ложь можно для построения более сложных проверок использовать до 64 вложенных друг в друга функций ЕСЛИ().
=ЕСЛИ(A1>=100;"Бюджет превышен";ЕСЛИ(A1>=90;"Крупный проект";ЕСЛИ(A1>=50;"Средний проект";"Малый проект ")))

Вышеуказанную формулу можно усложнять и дальше, но есть другие подходы:

=ПРОСМОТР(A1;{0;50;90;100};{"Малый проект";"Средний проект";"Крупный проект";"Бюджет превышен"})

=ВПР(A1;A3:B6;2)

Для функции ВПР() необходимо создать в диапазоне A3:B6 таблицу значений:

Если требуется вывести разный текст в случае наличия в ячейке А1 отрицательного значения, положительного значения или 0, то можно записать следующую формулу:

=ПРОСМОТР(A1;{-1E+307;0;1E-307};{"<0";"=0";">0"})

или, если требуется вместо текстовых значений вывести формулы, можно использовать ссылки на диапазон ячеек (содержащих формулы)

=ПРОСМОТР(A24;{-1E+307;0;1E-307};A27:A29) (см. файл примера)

Опущен третий аргумент [значение_если_ложь]

Третий аргумент функции не обязателен, если его опустить, то функция вернет значение ЛОЖЬ (если условие не выполнено).
=ЕСЛИ(A1>100;"Бюджет превышен")
Если в ячейке A1 содержится значение 1, то вышеуказанная формула вернет значение ЛОЖЬ.

Вместо ИСТИНА или ЛОЖЬ в первом аргументе введено число

Т.к. значение ЛОЖЬ эквивалентно 0, то формулы
=ЕСЛИ(0;"Бюджет превышен";"ОК!")
или (если в ячейке A1 содержится значение 0)
=ЕСЛИ(A1;"Бюджет превышен";"ОК!")

вернут ОК!

Если в ячейке A1 находится любое другое число кроме 0, то формула вернет Бюджет превышен. Такой подход удобен, когда проверяется равенство значения нулю.

Связь функции ЕСЛИ() с другими функциями использующие условия

EXCEL содержит также другие функции, которые можно применять для анализа данных с использованием условий. Например, для подсчета количества вхождений чисел в диапазоне ячеек используется функция СЧЁТЕСЛИ(), а для сложения значений, удовлетворяющих определенным условиям, используется функция СУММЕСЛИ().

Функция ЕСЛИ(), как альтернативный вариант, может быть также использована для подсчета и сложения значений с использованием условий. Ниже приведены иллюстрирующие примеры.

Пусть данные находятся в диапазоне A6:A11 (см. файл примера)

Подсчитаем сумму значений, которые больше 10 с помощью функции СУММЕСЛИ(), записав =СУММЕСЛИ(A6:A11;">10"). Аналогичный результат (23) можно получить с помощью формулы массива
=СУММ(ЕСЛИ(A6:A11>10;A6:A11))
(для ввода формулы в ячейку вместо ENTER нужно нажать CTRL+SHIFT+ENTER)

Теперь подсчитаем количество вхождений чисел больше 10 в диапазоне ячеек A6:A11 =СЧЁТЕСЛИ(A6:A11;">10"). Аналогичный результат (2) можно получить с помощью формулы массива
=СЧЁТ(ЕСЛИ(A6:A11>10;A6:A11))

Теперь, когда принцип понятен, с помощью функции ЕСЛИ() можно конструировать и другие формулы с условиями. Например, нахождение минимального значения среди чисел больше 10:
=МИН(ЕСЛИ(A6:A11>10;A6:A11))

Связанные статьи

Похожие задачи
Прочитайте другие статьи, решающие похожие задачи в MS Excel. Это позволит Вам решать широкий класс подобных задач.
Средняя: 4.5 (10 оценок)

Комментарии

Гость (не проверено)

Спасибо, очень здорово

Георгий (не проверено)

Помогите как это вычислить
При помощи функции ЕСЛИ вычислить функцию
_____x² при x>0
y = { x³ при x<0
_____x+1 при x=0

Creator

=ЕСЛИ(A1;ЕСЛИ(A1>0;A1^2;A1^3);A1+1)

Qwaszx

Очень плохо, что нельзя посмотреть файл примера. Статья очень полезная! Спасибо автору!

Creator

Чтобы скачать файл примера нажмите синюю кнопку внизу статьи

Beijing (не проверено)

=ЕСЛИ(И(D6>=1/1/2015;D6<=31/1/2015);"январь";"Значение вне интервала") - в чём ошибка формулы? Ячейка D6 со значением 01/01/2015

Creator

Значения дат нужно брать в кавычки. D6>"1/1/2015"

Анна

Подскажите пожалуйста, как правильно прописать формулу:

В ячейке N1 значение "с питанием", либо "без питания"
Если в N1 без питания, то формула расчета (I1+L1)*(1-13/100)
Если в N1 с питанием и L1=M1, то формула расчета (I1-O1)*(1-13/100)
Если в N1 с питанием и L1>M1, то формула расчета (I1-O1+((L1-M1)*300)*(1-13/100)
Если в N1 с питанием и L1

Creator

=ЕСЛИ(A33="без питания";1;ПРОСМОТР(A35-B35;{-1E+307;0;1E-307};I37:I39))

Формулы разместите в ячейках I37:I39,

A35-B35 - это Ваши L1 и M1, А33 - это Ваша N1

Это решение в файле примера (см. раздел Вложенные ЕСЛИ (2 уровня)). Хороший вопрос Вы задали!

Кстати, множитель 1-13/100 вынесите за скобки.

zlobkinavv

Подскажите пожалуйста, как прописать функцию "если" при следующем условии:
Если интересующий меня товар находится в столбце А, то брать соответсвующую ему цифру из столбца В, а если этот товар находится в столбце С, то брать соответсвующее ему значение из столбца D

Creator

Это нестандартная задача, у меня есть подозрение, что у Вас неправильно сформирована таблица (см. статью Советы по построению таблиц в MS EXCEL) Можете прислать таблицу и описание Вашей задачи на creator@excel2.ru