Функция СЧЁТЕСЛИ() в MS Excel - Подсчет значений с единственным критерием

Для подсчета ЧИСЛОвых значений, Дат и Текстовых значений, удовлетворяющих определенному критерию, существует простая и эффективная функция СЧЁТЕСЛИ(), английская версия COUNTIF(). Подсчитаем значения в диапазоне в случае одного критерия, а также покажем как ее использовать для подсчета неповторяющихся значений и вычисления ранга.

Синтаксис

СЧЁТЕСЛИ(диапазон;критерий)

Диапазон    — диапазон, в котором нужно подсчитать ячейки, содержащие числа, текст или даты.

Критерий    — критерий в форме числа, выражения, ссылки на ячейку или текста, который определяет, какие ячейки надо подсчитывать. Например, критерий может быть выражен следующим образом: 32, "32", ">32", "яблоки" или B4.

Подсчет числовых значений с одним критерием

Данные будем брать из диапазона A15:A25 (см. файл примера).

Критерий

Формула

Результат

Примечание

>=10

=СЧЁТЕСЛИ($A$2:$A$12; ">=10")

4

Подсчитывает количество ячеек, содержащих числа равных или более 10. Критерий указан в формуле

<=10
(ячейка С3)

=СЧЁТЕСЛИ( $A$2:$A$12;C3)

8

Подсчитывает количество ячеек, содержащих числа равных или меньших 10. Критерий указан через ссылку

>=
(ячейка С4)
11
(ячейка С5)

=СЧЁТЕСЛИ($A$2:$A$12; C4&C5)

3

Подсчитывает количество ячеек, содержащих числа равных или более 11. Критерий указан через ссылку и параметр

Примечание. О подсчете значений, удовлетворяющих нескольким критериям читайте в статье Подсчет значений со множественными критериями. О подсчете чисел с более чем 15 значащих цифр читайте статью Подсчет ТЕКСТовых значений с единственным критерием в MS EXCEL.

Подсчет Текстовых значений с одним критерием

Функция СЧЁТЕСЛИ() также годится для подсчета текстовых значений (см. Подсчет ТЕКСТовых значений с единственным критерием в MS EXCEL).

Подсчет дат с одним критерием

Так как любой дате в MS EXCEL соответствует определенное числовое значение, то настройка функции СЧЕТЕСЛИ() для дат не отличается от рассмотренного выше примера (см. файл примера Лист Даты). 

Если необходимо подсчитать количество дат, принадлежащих определенному месяцу, то нужно создать дополнительный столбец для вычисления месяца, затем записать формулу =СЧЁТЕСЛИ(B20:B30;2)

Подсчет с несколькими условиями

Обычно, в качестве аргумента критерий у функции СЧЁТЕСЛИ() указывают только одно значение. Например, =СЧЁТЕСЛИ(H2:H11;I2). Если в качестве критерия указать ссылку на целый диапазон ячеек с критериями, то функция вернет массив. В файле примера формула =СЧЁТЕСЛИ(A16:A25;C16:C18) возвращает массив {3:2:5}.

 

Для ввода формулы выделите диапазон ячеек такого же размера как и диапазон содержащий критерии. В Строке формул введите формулу и нажмите CTRL+SHIFT+ENTER, т.е. введите ее как формулу массива.

Это свойство функции СЧЁТЕСЛИ() используется в статье Отбор уникальных значений.

Специальные случаи использования функции

Возможность задать в качестве критерия несколько значений открывает дополнительные возможности использования функции СЧЁТЕСЛИ().

В файле примера на листе Специальное применение показано как с помощью функции СЧЁТЕСЛИ() вычислить количество повторов каждого значения в списке.

Выражение СЧЁТЕСЛИ(A6:A14;A6:A14) возвращает массив чисел {1:4:4:4:4:1:3:3:3}, который говорит о том, что значение 1 из списка в диапазоне А6:А15 - единственное, также в диапазоне 4 значения 2, одно значение 3, три значения 4. Это позволяет подсчитать количество неповторяющихся значений формулой =СУММПРОИЗВ(--(СЧЁТЕСЛИ(A6:A14;A6:A14)=1))

Формула =СЧЁТЕСЛИ(A6:A14;"<"&A6:A14)+1 вычисляет ранг по убыванию для каждого числа из диапазона А6:А15. В этом можно убедиться, выделив формулу в Строке формул и нажав клавишу F9. Значения совпадут с вычисленным рангом в столбце В (с помощью функции РАНГ()). Этот подход применен в статьях Динамическая сортировка таблицы в MS EXCEL и Отбор уникальных значений с сортировкой в MS EXCEL.

Связанные статьи

Похожие задачи
Прочитайте другие статьи, решающие похожие задачи в MS Excel. Это позволит Вам решать широкий класс подобных задач.
Средняя: 4 (7 оценок)