Разнесение в MS EXCEL ТЕКСТовых значений и ЧИСЕЛ по разным спискам

Если исходный список, содержит и текст и числа, то с помощью формул массива можно в один список отобрать все текстовые значения, а в другой – числовые.

Если случилось так, что исходный список содержит и текст и числа (список может содержать также и пропуски), то для дальнейшей работы бывает необходимо их разнести по разным спискам (см. файл примера).

Для выборки чисел используем формулу массива:
=ЕСЛИОШИБКА(ИНДЕКС(Список;НАИМЕНЬШИЙ(ЕСЛИ(ЕЧИСЛО(Список);СТРОКА(Список)-
МИН(СТРОКА(Список))+1;"");ЧСТРОК(C1:$C$1)));"")

Именованный диапазон Список представляет собой ссылку на исходный список в столбце А. Если в исходный диапазон планируется добавление значений, то лучше организовать Динамический диапазон.

Разберем формулу подробнее:

  • Формула ЕЧИСЛО(Список) возвращает массив {ЛОЖЬ:ЛОЖЬ:ИСТИНА:ИСТИНА:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА}, где ИСТИНА соответствует числу;
  • Функция ЕСЛИ() преобразует полученный массив ИСТИНА/ ЛОЖЬ в массив номеров позиций чисел {"":"":3:4:5:"":"":"":"":10} в диапазоне Список;
  • Функция НАИМЕНЬШИЙ() сортирует массив (для избавления от пропусков) и сопоставляет каждой строке номер позиции числа;
  • Функция ИНДЕКС() по номеру позиции из исходного списка выводит числа.

Аналогичную формулу запишем и для текстовых значений:
=ЕСЛИОШИБКА(ИНДЕКС(Список;НАИМЕНЬШИЙ(ЕСЛИ( ЕТЕКСТ(Список);СТРОКА(Список)-
МИН(СТРОКА(Список))+1;"");ЧСТРОК($D1:D$1)));"")

Конечно, списки содержащие текст и числа можно быстро разделить с помощью обычной сортировки (Данные/ Сортировка и фильтр/ Сортировка) и последующим копированием данных в другие столбцы через буфер обмена. Если же исходный список постоянно пополняется, то эти действия возможно нужно выполнять регулярно. Наличие вышеуказанных формул позволяет разделять список «на лету».

Как всегда - какой подход выбрать - решать разработчику.

Связанные статьи

Похожие задачи
Прочитайте другие статьи, решающие похожие задачи в MS Excel. Это позволит Вам решать широкий класс подобных задач.
Средняя: 5 (2 оценок)